Просмотр констант в списке, появляющимся в окне сообщений весьма затруднителен. Лучше вывод констант (и других представляемых в виде таблиц объектов) обеспечивается с использованием элемента диалога Таблица значений.
88. Создайте элемент в своей обработке: выберите вкладку Диалог, выберите Вставить | Таблица Значений, выберите место расположения, в поле Идентификатор введите тЗнач, нажмите ОК.
89. Измените размеры элемента Таблица значений.
90. Закомментируйте Пример 9
91. Введите код который выводит информацию о константах системы:
Пример 25.10. Вывод списка констант в диалоговом окне
// Пример 10
процедура СоздатьТаблЗнач( ) далее // Предварительное описание процедур
процедура ЗаполнитьТаблЗнач( ) далее
процедура Выполнить( ) // Связана с кнопкой Пуск обработки Проба
ОчиститьОкноСообщений( );
Сообщить("Переменная тЗнач имеет тип ТаблицаЗначений.");
конецПроцедуры // Выполнить
процедура ПриОткрытии( ) // Процедура выполняется перед открытием формы
// Создаем в таблице тЗнач три столбца
СоздатьТаблЗнач( ); // Вызов ранее описанной процедуры
// Заполняем таблицу тЗнач данными о непериодических константах
ЗаполнитьТаблЗнач( ); // Эта процедура также описана ранее
конецПроцедуры // Выполнить
// Процедура создает незаполненную таблицу значений
процедура СоздатьТаблЗнач( )
// Задаем при вызовах метода НоваяКолонка следующие параметры:
// идентификатор столбца;
// тип данных, заносимых в столбец;
// далее пропускаем два параметра - длину и точность представления данных;
// заголовок столбца
// Помним, что область действия переменной диалога тЗнач - все
// программные компоненты модуля; тип переменной тЗнач - ТаблицаЗначений
тЗнач.НоваяКолонка("иден", "Строка", , ,
"Идентификатор");
тЗнач.НоваяКолонка("син", "Строка", , ,
"Синоним");
тЗнач.НоваяКолонка("значен", "Строка", , ,
"Значение");
конецПроцедуры // СоздатьТаблЗнач
// Процедура заполняет таблицу значений данными о непериодических константах
процедура ЗаполнитьТаблЗнач( )
перем ин, син, иден, значен;
для ин = 1 по Метаданные.Константа( ) цикл
если Метаданные.Константа(ин).Периодический = 1 тогда
продолжить; // Значения периодических констант не выводятся
конецЕсли;
син = Метаданные.Константа(ин).Синоним;
// Выводим сообщения о константах, для которых задан синоним
если ПустоеЗначение(син) = 0 тогда
иден = Метаданные.Константа(ин).Идентификатор;
значен = Константа.ПолучитьАтрибут(иден);
// Используем для добавления новой строки в таблицу тЗнач метод НоваяСтрока
тЗнач.НоваяСтрока( ); // Добавляем новую строку в таблицу значений
тЗнач.иден = иден; // При занесении данных в ячейку столбца
тЗнач.син = син; // пользуемся его идентификатором
тЗнач.значен = сокрЛ(значен);
конецЕсли;
конецЦикла;
конецПроцедуры
92. Проверьте синтаксис.
93. Сохраните обработку: Ctrl+S.
94. Запустите 1С:Предприятие: F11, выберите Начало | Пуск, в таблице значений должны быть значения , синонимы и идентификаторы констант.